<%
'지정 패턴에 해당하는 문자열 치환
Function RegExpReplace(ByVal pattern, ByVal strText, ByVal strReplace)
Dim objRegExp
Set objRegExp = new RegExp
objRegExp.Pattern = pattern
objRegExp.Global = True
objRegExp.IgnoreCase = True
RegExpReplace = objRegExp.Replace(strText, strReplace)
Set objRegExp = Nothing
End Function
'패턴 매치 결과 컬렉션 반환
Function RegExpExec(ByVal pattern, ByVal strText)
Dim objRegExp
Set objRegExp = new RegExp
objRegExp.Pattern = pattern
objRegExp.Global = True
objRegExp.IgnoreCase = True
Set RegExpExec = objRegExp.Execute(strText)
Set objRegExp = Nothing
End Function
'지정 패턴에 해당하는 문자열을 추출하여 배열로 반환
Function RegExpArray(ByVal pattern, ByVal strText)
Dim objRegExp
Set objRegExp = new RegExp
objRegExp.Pattern = pattern
objRegExp.Global = True
objRegExp.IgnoreCase = True
Dim match, Matches, idx
Dim arrList()
idx = -1
Set Matches = objRegExp.Execute(strText)
If Matches.Count = 0 Then
RegExpArray = Null
Else
For Each match In Matches
idx = idx + 1
ReDim Preserve arrList(idx)
arrList(idx) = match
Next
RegExpArray = arrList
End If
Set objRegExp = Nothing
End Function
'본문내 포함된 이미지 태그 목록 추출
Function getImageTags(ByVal html)
getImageTags = RegExpArray("<img [^<>]*>", html)
End Function
'본문내 포함된 이미지 경로 목록 추출
Function getImageUrls(ByVal html)
getImageUrls = RegExpArray("[^=']*\.(gif|jpg|bmp)", html)
End Function
'본문내 태그 제거
Function removeTags(ByVal html)
removeTags = RegExpReplace("<[^>]+>", html, "")
End Function
%>
사용예제
<%
Dim content
Dim arrTag, arrUrl, idx
content = "<table><tr><td><img src='http://www.devholic.net/images/dev_logo.gif'></td></tr>"&_
"<tr><td><img src='http://www.devholic.net/images/left_text.gif'></td></tr>"&_
"<tr><td>DEVHolic</td></tr></table>"
arrTag = getImageTags(content)
arrUrl = getImageUrls(content)
If Not IsNull(arrTag) Then
For idx = 0 To UBound(arrTag)
Response.Write arrTag(idx) &"<br>"
Next
End If
If Not IsNull(arrUrl) Then
For idx = 0 To UBound(arrUrl)
Response.Write arrUrl(idx) &"<br>"
Next
End If
Response.Write removeTags(content) &"<br>"
%>